CMakeLists.txt

   1 project(lugaru)
   2
   3 cmake_minimum_required(VERSION 3.5)
   4 cmake_policy(SET CMP0004 OLD)
   5
   6 include(FindPkgConfig)
   7 include(GNUInstallDirs)
   8
   9
  10 ### Helpers
  11
  12 set(SRCDIR "${CMAKE_CURRENT_SOURCE_DIR}/Source")
  13
  14 if(UNIX AND NOT APPLE)
  15     set(LINUX TRUE)
  16 endif()
  17
  18
  19 ### CMake config
  20
  21 if(NOT CMAKE_BUILD_TYPE)
  22     set(CMAKE_BUILD_TYPE RelWithDebInfo)
  23 endif(NOT CMAKE_BUILD_TYPE)
  24 message("CMake build type: ${CMAKE_BUILD_TYPE}")
  25
  26 set(CMAKE_CXX_FLAGS "-Wall -Wno-parentheses -pedantic --std=c++11 ${CMAKE_CXX_FLAGS}")
  27
  28 if(APPLE)
  29     set(CMAKE_OSX_ARCHITECTURES "x86_64" CACHE STRING "Build architectures for OSX")
  30     set(CMAKE_OSX_DEPLOYMENT_TARGET "10.10" CACHE STRING
  31         "Minimum OS X version to target for deployment (at runtime); newer APIs weak linked. Set to empty string for default value")
  32     set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.10.sdk" CACHE PATH
  33         "The product will be built against the headers and libraries located inside the indicated SDK.")
  34 endif(APPLE)
  35
  36 if(LINUX)
  37     option(SYSTEM_INSTALL "Enable system-wide installation, with hardcoded data directory defined with CMAKE_INSTALL_DATADIR" OFF)
  38 endif(LINUX)
  39
  40 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  41
  42
  43 ### Sources
  44
  45 set(LUGARU_SRCS
  46     ${SRCDIR}/main.cpp
  47     ${SRCDIR}/Animation/Animation.cpp
  48     ${SRCDIR}/Animation/Joint.cpp
  49     ${SRCDIR}/Animation/Muscle.cpp
  50     ${SRCDIR}/Animation/Skeleton.cpp
  51     ${SRCDIR}/Frustum.cpp
  52     ${SRCDIR}/Account.cpp
  53     ${SRCDIR}/ConsoleCmds.cpp
  54     ${SRCDIR}/Dialog.cpp
  55     ${SRCDIR}/Hotspot.cpp
  56     ${SRCDIR}/Game.cpp
  57     ${SRCDIR}/GameDraw.cpp
  58     ${SRCDIR}/GameInitDispose.cpp
  59     ${SRCDIR}/GameTick.cpp
  60     ${SRCDIR}/Globals.cpp
  61     ${SRCDIR}/Lights.cpp
  62     ${SRCDIR}/Menu.cpp
  63     ${SRCDIR}/Models.cpp
  64     ${SRCDIR}/Objects.cpp
  65     ${SRCDIR}/pack.c
  66     ${SRCDIR}/Person.cpp
  67     ${SRCDIR}/private.c
  68     ${SRCDIR}/Quaternions.cpp
  69     ${SRCDIR}/Skybox.cpp
  70     ${SRCDIR}/Sprite.cpp
  71     ${SRCDIR}/Terrain.cpp
  72     ${SRCDIR}/Texture.cpp
  73     ${SRCDIR}/Text.cpp
  74     ${SRCDIR}/ImageIO.cpp
  75     ${SRCDIR}/unpack.c
  76     ${SRCDIR}/Weapons.cpp
  77     ${SRCDIR}/openal_wrapper.cpp
  78     ${SRCDIR}/Input.cpp
  79     ${SRCDIR}/Settings.cpp
  80     ${SRCDIR}/Stereo.cpp
  81     ${SRCDIR}/Sounds.cpp
  82     ${SRCDIR}/Awards.cpp
  83     ${SRCDIR}/Utils/Folders.cpp
  84 )
  85
  86 set(LUGARU_H
  87     ${SRCDIR}/Animation/Animation.h
  88     ${SRCDIR}/Animation/Joint.h
  89     ${SRCDIR}/Animation/Muscle.h
  90     ${SRCDIR}/Animation/Skeleton.h
  91     ${SRCDIR}/Frustum.h
  92     ${SRCDIR}/Account.h
  93     ${SRCDIR}/ConsoleCmds.h
  94     ${SRCDIR}/Dialog.h
  95     ${SRCDIR}/Hotspot.h
  96     ${SRCDIR}/Game.h
  97     ${SRCDIR}/Lights.h
  98     ${SRCDIR}/Menu.h
  99     ${SRCDIR}/Models.h
 100     ${SRCDIR}/Objects.h
 101     ${SRCDIR}/Person.h
 102     ${SRCDIR}/PhysicsMath.h
 103     ${SRCDIR}/Quaternions.h
 104     ${SRCDIR}/Random.h
 105     ${SRCDIR}/Skybox.h
 106     ${SRCDIR}/Sprite.h
 107     ${SRCDIR}/ImageIO.h
 108     ${SRCDIR}/Terrain.h
 109     ${SRCDIR}/Texture.h
 110     ${SRCDIR}/Text.h
 111     ${SRCDIR}/Weapons.h
 112     ${SRCDIR}/Input.h
 113     ${SRCDIR}/binio.h
 114     ${SRCDIR}/openal_wrapper.h
 115     ${SRCDIR}/optionparser.h
 116     ${SRCDIR}/gamegl.h
 117     ${SRCDIR}/private.h
 118     ${SRCDIR}/Settings.h
 119     ${SRCDIR}/Stereo.h
 120     ${SRCDIR}/Sounds.h
 121     ${SRCDIR}/Utils/Folders.h
 122 )
 123
 124 if(UNIX)
 125     set(LUGARU_SRCS
 126         ${LUGARU_SRCS}
 127         ${SRCDIR}/MacCompatibility.cpp
 128     )
 129     set(LUGARU_H
 130         ${LUGARU_H}
 131         ${SRCDIR}/MacCompatibility.h
 132     )
 133 endif(UNIX)
 134
 135 if(WIN32)
 136     add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 137                        COMMAND ${CMAKE_RC_COMPILER}
 138                        -I${SRCDIR}/win-res
 139                        -o ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 140                        -i${SRCDIR}/win-res/Lugaru.rc
 141                        DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 142     )
 143
 144     # FIXME: get rid of this.
 145     set(LUGARU_SRCS
 146         ${LUGARU_SRCS}
 147         ${SRCDIR}/WinDefs.cpp)
 148
 149     set(LUGARU_H
 150         ${LUGARU_H}
 151         ${SRCDIR}/WinDefs.h
 152         ${SRCDIR}/win-res/resource.h)
 153 endif(WIN32)
 154
 155 if(APPLE)
 156     set(PLATFORM_LIBS "-framework Carbon -framework Cocoa -framework OpenGL -framework OpenAL")
 157 endif(APPLE)
 158
 159
 160 ### Dependencies
 161
 162 find_package(OpenGL REQUIRED)
 163
 164 # Windows is funky about OpenAL detection
 165 if(WIN32)
 166     pkg_check_modules(OPENAL openal REQUIRED)
 167     set(OPENAL_LIBRARY ${OPENAL_LIBRARIES})
 168 else(WIN32)
 169     find_package(OpenAL REQUIRED)
 170 endif(WIN32)
 171
 172 find_package(sdl2 REQUIRED)
 173 find_package(PNG REQUIRED)
 174 find_package(JPEG REQUIRED)
 175 find_package(ZLIB REQUIRED)
 176 find_package(OggVorbis REQUIRED)
 177
 178 include_directories(
 179     ${OPENAL_INCLUDE_DIR}
 180     ${JPEG_INCLUDE_DIR}
 181     ${PNG_INCLUDE_DIR}
 182     ${ZLIB_INCLUDE_DIR}
 183     ${OPENGL_INCLUDE_DIR}
 184     ${SDL2_INCLUDE_DIRS}
 185     ${VORBISFILE_INCLUDE_DIR}
 186     ${OGG_INCLUDE_DIR}
 187     ${CMAKE_SOURCE_DIR}/Source
 188 )
 189
 190 set(LUGARU_LIBS ${OPENAL_LIBRARY} ${PNG_LIBRARY} ${JPEG_LIBRARY} ${ZLIB_LIBRARIES} ${SDL2_LIBRARIES} ${OPENGL_LIBRARIES} ${VORBISFILE_LIBRARY} ${OGG_LIBRARY} ${PLATFORM_LIBS})
 191
 192
 193 ### Definitions
 194
 195 if(WIN32)
 196     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H} lugaru_resource.obj)
 197 else(WIN32)
 198     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H})
 199 endif(WIN32)
 200
 201 target_link_libraries(lugaru ${LUGARU_LIBS})
 202
 203 if(WIN32)
 204     add_definitions(-DBinIO_STDINT_HEADER=<stdint.h>)
 205     if(MINGW)
 206         # An alternative would be to use _WIN32 consistently instead of WIN32
 207         add_definitions(-DWIN32)
 208     endif(MINGW)
 209 else(WIN32)
 210     add_definitions(-DPLATFORM_LINUX=1 -DPLATFORM_UNIX=1 -DBinIO_STDINT_HEADER=<stdint.h>)
 211 endif(WIN32)
 212
 213
 214 ### Installation
 215
 216 if(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 217     set(CMAKE_INSTALL_PREFIX "C:/Lugaru")
 218 endif(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 219
 220 # OS-specific installation paths
 221
 222 set(LUGARU_DOCDIR ${CMAKE_INSTALL_PREFIX})
 223 if(LINUX)
 224 endif(LINUX)
 225
 226 if(APPLE)
 227     set(LUGARU_APP_ROOT ${CMAKE_INSTALL_PREFIX}/Lugaru.app)
 228     set(LUGARU_BINDIR ${LUGARU_APP_ROOT}/Contents/MacOS)
 229     set(LUGARU_RESDIR ${LUGARU_APP_ROOT}/Resources)
 230 endif(APPLE)
 231
 232 # Actual installation instructions
 233
 234 if(WIN32)
 235     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru.exe DESTINATION ${CMAKE_INSTALL_PREFIX})
 236     install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 237     if(MINGW)
 238         # Based off Mageia/Fedora MinGW toolchain, might not work on other distros or Windows
 239         set(LIBGCC_S libgcc_s_sjlj-1.dll)
 240         if(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64") # MinGW64
 241             set(LIBGCC_S libgcc_s_seh-1.dll)
 242         endif(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")
 243         # FIXME: Filter out unneeded DLLs when building against some internal deps
 244         set(DLL_ROOT ${CMAKE_FIND_ROOT_PATH}/bin)
 245         install(FILES ${DLL_ROOT}/${LIBGCC_S}
 246                       ${DLL_ROOT}/libjpeg-62.dll
 247                       ${DLL_ROOT}/libogg-0.dll
 248                       ${DLL_ROOT}/libpng16-16.dll
 249                       ${DLL_ROOT}/libstdc++-6.dll
 250                       ${DLL_ROOT}/libvorbis-0.dll
 251                       ${DLL_ROOT}/libvorbisfile-3.dll
 252                       ${DLL_ROOT}/libwinpthread-1.dll
 253                       ${DLL_ROOT}/OpenAL32.dll
 254                       ${DLL_ROOT}/SDL2.dll
 255                       ${DLL_ROOT}/zlib1.dll
 256                 DESTINATION ${CMAKE_INSTALL_PREFIX})
 257     endif(MINGW)
 258 endif(WIN32)
 259
 260 if(LINUX)
 261     if(SYSTEM_INSTALL)
 262         add_definitions(-DDATA_DIR="${CMAKE_INSTALL_FULL_DATADIR}/${PROJECT_NAME}")
 263         set(LUGARU_DOCDIR ${CMAKE_INSTALL_DOCDIR})
 264         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_BINDIR})
 265         # Trailing '/' is significant, it installs and _renames_ Data/ as the destination folder
 266         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data/ DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
 267         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/appdata)
 268         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 269         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/128x128/apps)
 270         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.6 DESTINATION ${CMAKE_INSTALL_MANDIR}/man6)
 271     else(SYSTEM_INSTALL)
 272         message("You are building Lugaru without having enabled the SYSTEM_INSTALL option. It will default to looking for the data in the 'Data' directory next to the binary.")
 273         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_PREFIX})
 274         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 275     endif(SYSTEM_INSTALL)
 276 endif(LINUX)
 277
 278 if(APPLE)
 279     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${LUGARU_BINDIR})
 280     install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${LUGARU_APP_ROOT})
 281     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/lugaru.icns DESTINATION ${LUGARU_RESDIR})
 282     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/Info.plist DESTINATION ${LUGARU_APP_ROOT}/Contents)
 283 endif(APPLE)
 284
 285 # Documentation
 286
 287 install(FILES ${CMAKE_SOURCE_DIR}/AUTHORS
 288               ${CMAKE_SOURCE_DIR}/CONTENT-LICENSE.txt
 289               ${CMAKE_SOURCE_DIR}/COPYING.txt
 290               ${CMAKE_SOURCE_DIR}/DEBUG-OPTIONS.txt
 291               ${CMAKE_SOURCE_DIR}/README.md
 292         DESTINATION ${LUGARU_DOCDIR})