CMakeLists.txt

   1 project(lugaru)
   2
   3 cmake_minimum_required(VERSION 3.5)
   4 cmake_policy(SET CMP0004 OLD)
   5
   6 include(FindPkgConfig)
   7 include(GNUInstallDirs)
   8
   9
  10 ### Helpers
  11
  12 set(SRCDIR "${CMAKE_CURRENT_SOURCE_DIR}/Source")
  13
  14 if(UNIX AND NOT APPLE)
  15     set(LINUX TRUE)
  16 endif()
  17
  18
  19 ### CMake config
  20
  21 if(NOT CMAKE_BUILD_TYPE)
  22     set(CMAKE_BUILD_TYPE RelWithDebInfo)
  23 endif(NOT CMAKE_BUILD_TYPE)
  24 message("CMake build type: ${CMAKE_BUILD_TYPE}")
  25
  26 set(CMAKE_CXX_FLAGS "-Wall -Wno-parentheses -pedantic --std=c++11 ${CMAKE_CXX_FLAGS}")
  27
  28 if(APPLE)
  29     set(CMAKE_OSX_ARCHITECTURES "x86_64" CACHE STRING "Build architectures for OSX")
  30     set(CMAKE_OSX_DEPLOYMENT_TARGET "10.11" CACHE STRING
  31         "Minimum OS X version to target for deployment (at runtime); newer APIs weak linked. Set to empty string for default value")
  32     set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.11.sdk" CACHE PATH
  33         "The product will be built against the headers and libraries located inside the indicated SDK.")
  34 endif(APPLE)
  35
  36 if(LINUX)
  37     option(SYSTEM_INSTALL "Enable system-wide installation, with hardcoded data directory defined with CMAKE_INSTALL_DATADIR" OFF)
  38 endif(LINUX)
  39
  40 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/CMake/Modules/")
  41
  42
  43 ### Sources
  44
  45 set(LUGARU_SRCS
  46     ${SRCDIR}/main.cpp
  47     ${SRCDIR}/Animation/Animation.cpp
  48     ${SRCDIR}/Animation/Joint.cpp
  49     ${SRCDIR}/Animation/Muscle.cpp
  50     ${SRCDIR}/Animation/Skeleton.cpp
  51     ${SRCDIR}/Audio/openal_wrapper.cpp
  52     ${SRCDIR}/Audio/Sounds.cpp
  53     ${SRCDIR}/Devtools/ConsoleCmds.cpp
  54     ${SRCDIR}/Environment/Lights.cpp
  55     ${SRCDIR}/Environment/Skybox.cpp
  56     ${SRCDIR}/Environment/Terrain.cpp
  57     ${SRCDIR}/Graphic/Models.cpp
  58     ${SRCDIR}/Graphic/Sprite.cpp
  59     ${SRCDIR}/Graphic/Stereo.cpp
  60     ${SRCDIR}/Graphic/Text.cpp
  61     ${SRCDIR}/Graphic/Texture.cpp
  62     ${SRCDIR}/Level/Awards.cpp
  63     ${SRCDIR}/Level/Campaign.cpp
  64     ${SRCDIR}/Level/Dialog.cpp
  65     ${SRCDIR}/Level/Hotspot.cpp
  66     ${SRCDIR}/Math/Frustum.cpp
  67     ${SRCDIR}/Math/Quaternions.cpp
  68     ${SRCDIR}/Menu/Menu.cpp
  69     ${SRCDIR}/Objects/Objects.cpp
  70     ${SRCDIR}/Objects/Person.cpp
  71     ${SRCDIR}/Objects/Weapons.cpp
  72     ${SRCDIR}/User/Account.cpp
  73     ${SRCDIR}/User/Settings.cpp
  74     ${SRCDIR}/Utils/Folders.cpp
  75     ${SRCDIR}/Utils/ImageIO.cpp
  76     ${SRCDIR}/Utils/Input.cpp
  77     ${SRCDIR}/Utils/pack.c
  78     ${SRCDIR}/Utils/private.c
  79     ${SRCDIR}/Utils/unpack.c
  80     ${SRCDIR}/Game.cpp
  81     ${SRCDIR}/GameDraw.cpp
  82     ${SRCDIR}/GameInitDispose.cpp
  83     ${SRCDIR}/GameTick.cpp
  84     ${SRCDIR}/Globals.cpp
  85
  86 )
  87
  88 set(LUGARU_H
  89     ${SRCDIR}/Animation/Animation.hpp
  90     ${SRCDIR}/Animation/Joint.hpp
  91     ${SRCDIR}/Animation/Muscle.hpp
  92     ${SRCDIR}/Animation/Skeleton.hpp
  93     ${SRCDIR}/Audio/openal_wrapper.hpp
  94     ${SRCDIR}/Audio/Sounds.hpp
  95     ${SRCDIR}/Devtools/ConsoleCmds.hpp
  96     ${SRCDIR}/Environment/Lights.hpp
  97     ${SRCDIR}/Environment/Skybox.hpp
  98     ${SRCDIR}/Environment/Terrain.hpp
  99     ${SRCDIR}/Graphic/gamegl.hpp
 100     ${SRCDIR}/Graphic/Models.hpp
 101     ${SRCDIR}/Graphic/Sprite.hpp
 102     ${SRCDIR}/Graphic/Stereo.hpp
 103     ${SRCDIR}/Graphic/Text.hpp
 104     ${SRCDIR}/Graphic/Texture.hpp
 105     ${SRCDIR}/Level/Campaign.hpp
 106     ${SRCDIR}/Level/Dialog.hpp
 107     ${SRCDIR}/Level/Hotspot.hpp
 108     ${SRCDIR}/Math/Frustum.hpp
 109     ${SRCDIR}/Math/PhysicsMath.hpp
 110     ${SRCDIR}/Math/Quaternions.hpp
 111     ${SRCDIR}/Math/Random.hpp
 112     ${SRCDIR}/Menu/Menu.hpp
 113     ${SRCDIR}/Objects/Objects.hpp
 114     ${SRCDIR}/Objects/Person.hpp
 115     ${SRCDIR}/Objects/Weapons.hpp
 116     ${SRCDIR}/Thirdparty/optionparser.h
 117     ${SRCDIR}/User/Account.hpp
 118     ${SRCDIR}/User/Settings.hpp
 119     ${SRCDIR}/Utils/binio.h
 120     ${SRCDIR}/Utils/Folders.hpp
 121     ${SRCDIR}/Utils/ImageIO.hpp
 122     ${SRCDIR}/Utils/Input.hpp
 123     ${SRCDIR}/Utils/private.h
 124     ${SRCDIR}/Game.hpp
 125
 126 )
 127
 128 if(UNIX)
 129     set(LUGARU_SRCS
 130         ${LUGARU_SRCS}
 131         ${SRCDIR}/MacCompatibility.cpp
 132     )
 133     set(LUGARU_H
 134         ${LUGARU_H}
 135         ${SRCDIR}/MacCompatibility.hpp
 136     )
 137 endif(UNIX)
 138
 139 if(WIN32)
 140     add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 141                        COMMAND ${CMAKE_RC_COMPILER}
 142                        -I${SRCDIR}/win-res
 143                        -o ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 144                        -i${SRCDIR}/win-res/Lugaru.rc
 145                        DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 146     )
 147
 148     # FIXME: get rid of this.
 149     set(LUGARU_SRCS
 150         ${LUGARU_SRCS}
 151         ${SRCDIR}/WinDefs.cpp)
 152
 153     set(LUGARU_H
 154         ${LUGARU_H}
 155         ${SRCDIR}/WinDefs.hpp
 156         ${SRCDIR}/win-res/resource.hpp)
 157 endif(WIN32)
 158
 159 if(APPLE)
 160     set(PLATFORM_LIBS "-framework Carbon -framework Cocoa -framework OpenGL -framework OpenAL")
 161 endif(APPLE)
 162
 163
 164 ### Dependencies
 165
 166 find_package(OpenGL REQUIRED)
 167
 168 # Windows is funky about OpenAL detection
 169 if(WIN32)
 170     pkg_check_modules(OPENAL openal REQUIRED)
 171     set(OPENAL_LIBRARY ${OPENAL_LIBRARIES})
 172 else(WIN32)
 173     find_package(OpenAL REQUIRED)
 174 endif(WIN32)
 175
 176 find_package(sdl2 REQUIRED)
 177 find_package(PNG REQUIRED)
 178 find_package(JPEG REQUIRED)
 179 find_package(ZLIB REQUIRED)
 180 find_package(OggVorbis REQUIRED)
 181
 182 include_directories(
 183     ${OPENAL_INCLUDE_DIR}
 184     ${JPEG_INCLUDE_DIR}
 185     ${PNG_INCLUDE_DIR}
 186     ${ZLIB_INCLUDE_DIR}
 187     ${OPENGL_INCLUDE_DIR}
 188     ${SDL2_INCLUDE_DIRS}
 189     ${VORBISFILE_INCLUDE_DIR}
 190     ${OGG_INCLUDE_DIR}
 191     ${CMAKE_SOURCE_DIR}/Source
 192 )
 193
 194 set(LUGARU_LIBS ${OPENAL_LIBRARY} ${PNG_LIBRARY} ${JPEG_LIBRARY} ${ZLIB_LIBRARIES} ${SDL2_LIBRARIES} ${OPENGL_LIBRARIES} ${VORBISFILE_LIBRARY} ${OGG_LIBRARY} ${PLATFORM_LIBS})
 195
 196
 197 ### Definitions
 198
 199 if(WIN32)
 200     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H} lugaru_resource.obj)
 201 else(WIN32)
 202     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H})
 203 endif(WIN32)
 204
 205 target_link_libraries(lugaru ${LUGARU_LIBS})
 206
 207 if(WIN32)
 208     add_definitions(-DBinIO_STDINT_HEADER=<stdint.h>)
 209     if(MINGW)
 210         # An alternative would be to use _WIN32 consistently instead of WIN32
 211         add_definitions(-DWIN32)
 212     endif(MINGW)
 213 else(WIN32)
 214     add_definitions(-DPLATFORM_LINUX=1 -DPLATFORM_UNIX=1 -DBinIO_STDINT_HEADER=<stdint.h>)
 215 endif(WIN32)
 216
 217
 218 ### Installation
 219
 220 if(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 221     set(CMAKE_INSTALL_PREFIX "C:/Lugaru")
 222 endif(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 223
 224 # OS-specific installation paths
 225
 226 set(LUGARU_DOCDIR ${CMAKE_INSTALL_PREFIX})
 227 if(LINUX)
 228 endif(LINUX)
 229
 230 if(APPLE)
 231     set(LUGARU_APP_ROOT ${CMAKE_INSTALL_PREFIX}/Lugaru.app)
 232     set(LUGARU_BINDIR ${LUGARU_APP_ROOT}/Contents/MacOS)
 233     set(LUGARU_RESDIR ${LUGARU_APP_ROOT}/Resources)
 234 endif(APPLE)
 235
 236 # Actual installation instructions
 237
 238 if(WIN32)
 239     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru.exe DESTINATION ${CMAKE_INSTALL_PREFIX})
 240     install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 241     if(MINGW)
 242         # Based off Mageia/Fedora MinGW toolchain, might not work on other distros or Windows
 243         set(LIBGCC_S libgcc_s_sjlj-1.dll)
 244         if(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64") # MinGW64
 245             set(LIBGCC_S libgcc_s_seh-1.dll)
 246         endif(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")
 247         # FIXME: Filter out unneeded DLLs when building against some internal deps
 248         set(DLL_ROOT ${CMAKE_FIND_ROOT_PATH}/bin)
 249         install(FILES ${DLL_ROOT}/${LIBGCC_S}
 250                       ${DLL_ROOT}/libjpeg-62.dll
 251                       ${DLL_ROOT}/libogg-0.dll
 252                       ${DLL_ROOT}/libpng16-16.dll
 253                       ${DLL_ROOT}/libstdc++-6.dll
 254                       ${DLL_ROOT}/libvorbis-0.dll
 255                       ${DLL_ROOT}/libvorbisfile-3.dll
 256                       ${DLL_ROOT}/libwinpthread-1.dll
 257                       ${DLL_ROOT}/OpenAL32.dll
 258                       ${DLL_ROOT}/SDL2.dll
 259                       ${DLL_ROOT}/zlib1.dll
 260                 DESTINATION ${CMAKE_INSTALL_PREFIX})
 261     endif(MINGW)
 262 endif(WIN32)
 263
 264 if(LINUX)
 265     if(SYSTEM_INSTALL)
 266         add_definitions(-DDATA_DIR="${CMAKE_INSTALL_FULL_DATADIR}/${PROJECT_NAME}")
 267         set(LUGARU_DOCDIR ${CMAKE_INSTALL_DOCDIR})
 268         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_BINDIR})
 269         # Trailing '/' is significant, it installs and _renames_ Data/ as the destination folder
 270         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data/ DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
 271         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/appdata)
 272         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 273         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/128x128/apps)
 274         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.6 DESTINATION ${CMAKE_INSTALL_MANDIR}/man6)
 275     else(SYSTEM_INSTALL)
 276         message("You are building Lugaru without having enabled the SYSTEM_INSTALL option. It will default to looking for the data in the 'Data' directory next to the binary.")
 277         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_PREFIX})
 278         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 279     endif(SYSTEM_INSTALL)
 280 endif(LINUX)
 281
 282 if(APPLE)
 283     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${LUGARU_BINDIR})
 284     install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${LUGARU_APP_ROOT})
 285     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/Lugaru.icns DESTINATION ${LUGARU_RESDIR})
 286     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/Info.plist DESTINATION ${LUGARU_APP_ROOT}/Contents)
 287 endif(APPLE)
 288
 289 # Documentation
 290
 291 install(FILES ${CMAKE_SOURCE_DIR}/AUTHORS
 292               ${CMAKE_SOURCE_DIR}/CONTENT-LICENSE.txt
 293               ${CMAKE_SOURCE_DIR}/COPYING.txt
 294               ${CMAKE_SOURCE_DIR}/README.md
 295               ${CMAKE_SOURCE_DIR}/RELEASE-NOTES.md
 296               ${CMAKE_SOURCE_DIR}/Docs/DEVTOOLS.txt
 297               ${CMAKE_SOURCE_DIR}/Docs/README.Empire.txt
 298               ${CMAKE_SOURCE_DIR}/Docs/README.Temple.txt
 299         DESTINATION ${LUGARU_DOCDIR})