CMakeLists.txt

   1 project(lugaru)
   2
   3 cmake_minimum_required(VERSION 2.6)
   4
   5 set(SRCDIR "${CMAKE_CURRENT_SOURCE_DIR}/Source")
   6 set(DEPDIR "${CMAKE_CURRENT_SOURCE_DIR}/Dependencies")
   7
   8 if(NOT CMAKE_BUILD_TYPE)
   9   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  10       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel"
  11       FORCE)
  12 endif(NOT CMAKE_BUILD_TYPE)
  13
  14 if(NOT LUGARU_INSTALL_PREFIX)
  15   if(WIN32)
  16      set(LUGARU_INSTALL_PREFIX "C:/Lugaru" CACHE PATH
  17      "LUGARU_INSTALL_PREFIX: Install path prefix, prepended onto install directories."
  18       FORCE)
  19   else(WIN32)
  20      set(LUGARU_INSTALL_PREFIX "/usr/local/lugaru" CACHE PATH
  21      "CMAKE_INSTALL_PREFIX: Install path prefix, prepended onto install directories."
  22       FORCE)
  23   endif(WIN32)
  24 endif(NOT LUGARU_INSTALL_PREFIX)
  25
  26 set(CMAKE_INSTALL_PREFIX "${LUGARU_INSTALL_PREFIX}" CACHE INTERNAL "Prefix prepended to install directories" FORCE)
  27
  28 if(MINGW)
  29         set(OPENGL_gl_LIBRARY "-lopengl32" CACHE STRING "OpenGL library for Win32" FORCE)
  30         set(OPENGL_glu_LIBRARY "-lglu32" CACHE STRING "GLU library for Win32" FORCE)
  31 endif(MINGW)
  32
  33 if(APPLE)
  34         set(CMAKE_OSX_ARCHITECTURES "i386;x86_64;ppc" CACHE STRING "Build architectures for OSX")
  35         set(CMAKE_OSX_DEPLOYMENT_TARGET "10.5" CACHE STRING
  36                 "Minimum OS X version to target for deployment (at runtime); newer APIs weak linked. Set to empty string for default value")
  37         set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.5.sdk" CACHE PATH
  38                 "The product will be built against the headers and libraries located inside the indicated SDK.")
  39 endif(APPLE)
  40
  41 if(APPLE)
  42         # Save our sanity; Set all available libraries to internal by default
  43         set(LUGARU_FORCE_INTERNAL_SDL True)
  44         set(LUGARU_FORCE_INTERNAL_GLU True)
  45         set(LUGARU_FORCE_INTERNAL_JPEG True)
  46         set(LUGARU_FORCE_INTERNAL_PNG True)
  47         set(LUGARU_FORCE_INTERNAL_VORBIS True)
  48         set(LUGARU_FORCE_INTERNAL_ZLIB True)
  49 endif(APPLE)
  50
  51 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  52
  53 set(LUGARU_SRCS
  54         ${SRCDIR}/Frustum.cpp
  55         ${SRCDIR}/Account.cpp
  56         ${SRCDIR}/Game.cpp
  57         ${SRCDIR}/GameDraw.cpp
  58         ${SRCDIR}/GameInitDispose.cpp
  59         ${SRCDIR}/GameTick.cpp
  60         ${SRCDIR}/Globals.cpp
  61         ${SRCDIR}/Lights.cpp
  62         ${SRCDIR}/Models.cpp
  63         ${SRCDIR}/Objects.cpp
  64         ${SRCDIR}/pack.c
  65         ${SRCDIR}/pack_private.c
  66         ${SRCDIR}/Person.cpp
  67         ${SRCDIR}/private.c
  68         ${SRCDIR}/Quaternions.cpp
  69         ${SRCDIR}/Random.c
  70         ${SRCDIR}/Skeleton.cpp
  71         ${SRCDIR}/Skybox.cpp
  72         ${SRCDIR}/Sprite.cpp
  73         ${SRCDIR}/Terrain.cpp
  74         ${SRCDIR}/Text.cpp
  75         ${SRCDIR}/TGALoader.cpp
  76         ${SRCDIR}/unpack.c
  77         ${SRCDIR}/unpack_private.c
  78         ${SRCDIR}/Weapons.cpp
  79         ${SRCDIR}/OpenGL_Windows.cpp
  80         ${SRCDIR}/openal_wrapper.cpp
  81         ${SRCDIR}/Input.cpp
  82         ${SRCDIR}/Settings.cpp
  83         ${SRCDIR}/Stereo.cpp
  84 )
  85
  86 set(LUGARU_H
  87         ${SRCDIR}/Constants.h
  88         ${SRCDIR}/Frustum.h
  89         ${SRCDIR}/Account.h
  90         ${SRCDIR}/Game.h
  91         ${SRCDIR}/Lights.h
  92         ${SRCDIR}/LinkedList.h
  93         ${SRCDIR}/Models.h
  94         ${SRCDIR}/Objects.h
  95         ${SRCDIR}/Person.h
  96         ${SRCDIR}/PhysicsMath.h
  97         ${SRCDIR}/Pointer.h
  98         ${SRCDIR}/Quaternions.h
  99         ${SRCDIR}/Random.h
 100         ${SRCDIR}/Skeleton.h
 101         ${SRCDIR}/Skybox.h
 102         ${SRCDIR}/Sprite.h
 103         ${SRCDIR}/TGALoader.h
 104         ${SRCDIR}/Terrain.h
 105         ${SRCDIR}/Text.h
 106         ${SRCDIR}/Weapons.h
 107         ${SRCDIR}/Input.h
 108         ${SRCDIR}/alstubs.h
 109         ${SRCDIR}/binio.h
 110         ${SRCDIR}/openal_wrapper.h
 111         ${SRCDIR}/gamegl.h
 112         ${SRCDIR}/glstubs.h
 113         ${SRCDIR}/mmgr.h
 114         ${SRCDIR}/nommgr.h
 115         ${SRCDIR}/pack_private.h
 116         ${SRCDIR}/private.h
 117         ${SRCDIR}/unpack_private.h
 118         ${SRCDIR}/Settings.h
 119         ${SRCDIR}/Stereo.h
 120 )
 121
 122 if(UNIX)
 123         set(LUGARU_SRCS
 124                 ${LUGARU_SRCS}
 125                 ${SRCDIR}/MacCompatibility.cpp
 126         )
 127         set(LUGARU_H
 128                 ${LUGARU_H}
 129                 ${SRCDIR}/MacCompatibility.h
 130         )
 131 endif(UNIX)
 132
 133 if(MSVC) # MSVC non-C99 support biting us hard
 134         set(LUGARU_H
 135                 ${LUGARU_H}
 136                 ${DEPDIR}/msinttypes/stdint.h
 137                 ${DEPDIR}/msinttypes/inttypes.h
 138         )
 139 endif(MSVC)
 140
 141 if(WIN32)
 142   if(CMAKE_CROSSCOMPILING)
 143     ADD_CUSTOM_COMMAND( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 144                                                   COMMAND i686-pc-mingw32-windres
 145                                                           -I${SRCDIR}/win-res
 146                                                           -o ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 147                                                           -i${SRCDIR}/win-res/Lugaru.rc
 148                                               DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 149                                                   )
 150   endif(CMAKE_CROSSCOMPILING)
 151   if(NOT CMAKE_CROSSCOMPILING)
 152    if(MSVC)
 153     ADD_CUSTOM_COMMAND( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 154                                                   COMMAND rc
 155                                                           -I${SRCDIR}/win-res
 156                                                           -fo${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 157                                                           ${SRCDIR}/win-res/Lugaru.rc
 158                                               DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 159                                                   )
 160    endif(MSVC)
 161    if(MINGW)
 162     ADD_CUSTOM_COMMAND( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 163                                                   COMMAND windres
 164                                                           -I${SRCDIR}/win-res
 165                                                           -o ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 166                                                           -i${SRCDIR}/win-res/Lugaru.rc
 167                                               DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 168                                                   )
 169    endif(MINGW)
 170   endif(NOT CMAKE_CROSSCOMPILING)
 171
 172   # !!! FIXME: get rid of this.
 173   set(LUGARU_SRCS
 174         ${LUGARU_SRCS}
 175         ${SRCDIR}/WinDefs.cpp)
 176
 177   set(LUGARU_H
 178         ${LUGARU_H}
 179         ${SRCDIR}/WinDefs.h
 180         ${SRCDIR}/win-res/resource.h)
 181 endif(WIN32)
 182
 183 if (APPLE)
 184     set(PLATFORM_LIBS "-framework Carbon -framework Cocoa -framework OpenGL -framework OpenAL")
 185 endif (APPLE)
 186
 187 # Deal with dependencies...
 188 find_package(OpenGL REQUIRED)
 189 # force this include dir no matter what on Windows, so we get sane headers.
 190 if(NOT WIN32)
 191         option (LUGARU_FORCE_INTERNAL_OPENGL "Force internal OpenGL headers, even if there's a system version" True)
 192         if (LUGARU_FORCE_INTERNAL_OPENGL)
 193                 include_directories("${DEPDIR}/OpenGL")
 194         endif (LUGARU_FORCE_INTERNAL_OPENGL)
 195 endif(NOT WIN32)
 196
 197 if(WIN32)
 198         include_directories("${DEPDIR}/OpenGL")
 199 endif(WIN32)
 200
 201 if(MSVC) # More Visual Studio annoyances
 202         include_directories("${DEPDIR}/msinttypes")
 203 endif(MSVC)
 204
 205 option (LUGARU_FORCE_INTERNAL_OPENAL "Force internal libOpenAL, even if there's a system version" False)
 206 if (NOT LUGARU_FORCE_INTERNAL_OPENAL)
 207         find_package(OpenAL REQUIRED)
 208 else(NOT LUGARU_FORCE_INTERNAL_OPENAL)
 209         set(OPENAL_FOUND False)
 210 endif (NOT LUGARU_FORCE_INTERNAL_OPENAL)
 211
 212 if (NOT OPENAL_FOUND OR LUGARU_FORCE_INTERNAL_OPENAL)
 213     message(STATUS "Using internal copy of OpenAL")
 214     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} OpenAL")
 215     set(OPENALDIR "${DEPDIR}/OpenAL")
 216     set(OPENAL_INCLUDE_DIR "${OPENALDIR}/include/AL")
 217     set(OPENAL_LIBRARY "")
 218
 219     if (WIN32)
 220         set(LUGARU_HAS_INTERNAL_OPENAL True)
 221         if (MSVC80)
 222             set(OPENAL_LIBRARY
 223                 ${OPENALDIR}/lib/win32/msvc2005/OpenAL32.lib
 224             )
 225         endif (MSVC80)
 226         if (MSVC90)
 227             set(OPENAL_LIBRARY
 228                 ${OPENALDIR}/lib/win32/msvc2008/OpenAL32.lib
 229             )
 230         endif (MSVC90)
 231         if (MINGW)
 232             set(OPENAL_LIBRARY
 233                 ${OPENALDIR}/lib/win32/mingw/libOpenAL32.dll.a
 234             )
 235         endif (MINGW)
 236      endif(WIN32)
 237
 238     if (NOT LUGARU_HAS_INTERNAL_OPENAL)
 239         message(ERROR "We don't have a prebuilt OpenAL for this platform.")
 240     endif (NOT LUGARU_HAS_INTERNAL_OPENAL)
 241 endif (NOT OPENAL_FOUND OR LUGARU_FORCE_INTERNAL_OPENAL)
 242
 243 option (LUGARU_FORCE_INTERNAL_SDL "Force internal libSDL, even if there's a system version" False)
 244 if (NOT LUGARU_FORCE_INTERNAL_SDL)
 245     find_package(SDL)
 246 else(NOT LUGARU_FORCE_INTERNAL_SDL)
 247         set(SDL_FOUND False)
 248 endif (NOT LUGARU_FORCE_INTERNAL_SDL)
 249
 250 if (NOT SDL_FOUND)
 251     message(STATUS "Using internal copy of SDL")
 252     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} SDL")
 253     set(SDLDIR "${DEPDIR}/SDL12")
 254     set(SDL_INCLUDE_DIR "${SDLDIR}/include")
 255     set(SDL_LIBRARY "")
 256     if (APPLE)
 257         set(LUGARU_HAS_INTERNAL_SDL True)
 258         set(SDL_LIBRARY
 259             ${SDLDIR}/lib/macosx/libSDL-1.2.0.dylib
 260             ${SDLDIR}/lib/macosx/libSDLmain-osx.a
 261         )
 262     endif (APPLE)
 263
 264     if (WIN32)
 265         set(LUGARU_HAS_INTERNAL_SDL True)
 266         if (MSVC80)
 267           set(SDL_LIBRARY
 268               ${SDLDIR}/lib/win32/msvc2005/SDLmain.lib
 269               ${SDLDIR}/lib/win32/msvc2005/SDL.lib
 270           )
 271         endif (MSVC80)
 272         if (MSVC90)
 273           set(SDL_LIBRARY
 274               ${SDLDIR}/lib/win32/msvc2008/SDLmain.lib
 275               ${SDLDIR}/lib/win32/msvc2008/SDL.lib
 276           )
 277         endif (MSVC90)
 278         if (MINGW)
 279           set(SDL_LIBRARY
 280               "mingw32"
 281               ${SDLDIR}/lib/win32/mingw/libSDLmain.a
 282               ${SDLDIR}/lib/win32/mingw/libSDL.dll.a
 283               "-mwindows"
 284           )
 285         endif (MINGW)
 286     endif (WIN32)
 287
 288     if (NOT LUGARU_HAS_INTERNAL_SDL)
 289         message(ERROR "We don't have a prebuilt SDL for this platform.")
 290     endif (NOT LUGARU_HAS_INTERNAL_SDL)
 291 endif (NOT SDL_FOUND)
 292
 293 option (LUGARU_FORCE_INTERNAL_PNG "Force internal libPNG, even if there's a system version" False)
 294 if (NOT LUGARU_FORCE_INTERNAL_PNG)
 295     find_package(PNG)
 296 else(NOT LUGARU_FORCE_INTERNAL_PNG)
 297         set(PNG_FOUND False)
 298 endif (NOT LUGARU_FORCE_INTERNAL_PNG)
 299
 300 if (NOT PNG_FOUND)
 301     message(STATUS "Using internal copy of libpng")
 302     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} PNG")
 303     set(PNGDIR "${DEPDIR}/libpng")
 304     set(PNG_INCLUDE_DIR "${PNGDIR}")
 305     set(PNG_LIBRARY "")
 306     set(LUGARU_SRCS
 307         ${LUGARU_SRCS}
 308         ${PNGDIR}/png.c
 309         ${PNGDIR}/pngerror.c
 310         ${PNGDIR}/pngget.c
 311         ${PNGDIR}/pngmem.c
 312         ${PNGDIR}/pngpread.c
 313         ${PNGDIR}/pngread.c
 314         ${PNGDIR}/pngrio.c
 315         ${PNGDIR}/pngrtran.c
 316         ${PNGDIR}/pngrutil.c
 317         ${PNGDIR}/pngset.c
 318         ${PNGDIR}/pngtrans.c
 319         ${PNGDIR}/pngwio.c
 320         ${PNGDIR}/pngwrite.c
 321         ${PNGDIR}/pngwtran.c
 322         ${PNGDIR}/pngwutil.c
 323     )
 324 endif (NOT PNG_FOUND)
 325
 326 option (LUGARU_FORCE_INTERNAL_JPEG "Force internal libJPEG, even if there's a system version" False)
 327 if (NOT LUGARU_FORCE_INTERNAL_JPEG)
 328     find_package(JPEG)
 329 else(NOT LUGARU_FORCE_INTERNAL_JPEG)
 330         set(JPEG_FOUND False)
 331 endif (NOT LUGARU_FORCE_INTERNAL_JPEG)
 332
 333 if (NOT JPEG_FOUND)
 334     message(STATUS "Using internal copy of libjpeg")
 335     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} JPEG")
 336     set(JPEGDIR "${DEPDIR}/libjpeg")
 337     set(JPEG_INCLUDE_DIR "${JPEGDIR}")
 338     set(JPEG_LIBRARY "")
 339     set(LUGARU_SRCS
 340         ${LUGARU_SRCS}
 341         ${JPEGDIR}/jdapistd.c
 342         ${JPEGDIR}/jdmaster.c
 343         ${JPEGDIR}/jdapimin.c
 344         ${JPEGDIR}/jcapimin.c
 345         ${JPEGDIR}/jdmerge.c
 346         ${JPEGDIR}/jdatasrc.c
 347         ${JPEGDIR}/jdatadst.c
 348         ${JPEGDIR}/jdcoefct.c
 349         ${JPEGDIR}/jdcolor.c
 350         ${JPEGDIR}/jddctmgr.c
 351         ${JPEGDIR}/jdhuff.c
 352         ${JPEGDIR}/jdinput.c
 353         ${JPEGDIR}/jdmainct.c
 354         ${JPEGDIR}/jdmarker.c
 355         ${JPEGDIR}/jdpostct.c
 356         ${JPEGDIR}/jdsample.c
 357         ${JPEGDIR}/jdtrans.c
 358         ${JPEGDIR}/jerror.c
 359         ${JPEGDIR}/jidctflt.c
 360         ${JPEGDIR}/jidctfst.c
 361         ${JPEGDIR}/jidctint.c
 362         ${JPEGDIR}/jmemmgr.c
 363         ${JPEGDIR}/jutils.c
 364         ${JPEGDIR}/jmemnobs.c
 365         ${JPEGDIR}/jquant1.c
 366         ${JPEGDIR}/jquant2.c
 367         ${JPEGDIR}/jcomapi.c
 368         ${JPEGDIR}/jcmarker.c
 369         ${JPEGDIR}/jcapistd.c
 370         ${JPEGDIR}/jcparam.c
 371         ${JPEGDIR}/jcinit.c
 372         ${JPEGDIR}/jcdctmgr.c
 373         ${JPEGDIR}/jccoefct.c
 374         ${JPEGDIR}/jcmainct.c
 375         ${JPEGDIR}/jfdctflt.c
 376         ${JPEGDIR}/jfdctint.c
 377         ${JPEGDIR}/jfdctfst.c
 378         ${JPEGDIR}/jchuff.c
 379         ${JPEGDIR}/jcsample.c
 380         ${JPEGDIR}/jcmaster.c
 381         ${JPEGDIR}/jccolor.c
 382         ${JPEGDIR}/jcprepct.c
 383         ${JPEGDIR}/jcarith.c
 384         ${JPEGDIR}/jdarith.c
 385         ${JPEGDIR}/jaricom.c
 386     )
 387 endif (NOT JPEG_FOUND)
 388
 389 option (LUGARU_FORCE_INTERNAL_ZLIB "Force internal zlib, even if there's a system version" False)
 390 if (NOT LUGARU_FORCE_INTERNAL_ZLIB)
 391     find_package(ZLIB)
 392 else(NOT LUGARU_FORCE_INTERNAL_ZLIB)
 393         set(ZLIB_FOUND False)
 394 endif (NOT LUGARU_FORCE_INTERNAL_ZLIB)
 395
 396 if (NOT ZLIB_FOUND)
 397     message(STATUS "Using internal copy of zlib")
 398     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} ZLIB")
 399     set(ZLIBDIR "${DEPDIR}/zlib")
 400     set(ZLIB_INCLUDE_DIR "${ZLIBDIR}")
 401     set(ZLIB_LIBRARIES "")
 402     set(LUGARU_SRCS
 403         ${LUGARU_SRCS}
 404         ${ZLIBDIR}/adler32.c
 405         ${ZLIBDIR}/compress.c
 406         ${ZLIBDIR}/crc32.c
 407         ${ZLIBDIR}/deflate.c
 408         ${ZLIBDIR}/infback.c
 409         ${ZLIBDIR}/inffast.c
 410         ${ZLIBDIR}/inflate.c
 411         ${ZLIBDIR}/inftrees.c
 412         ${ZLIBDIR}/trees.c
 413         ${ZLIBDIR}/uncompr.c
 414         ${ZLIBDIR}/zutil.c
 415     )
 416 endif (NOT ZLIB_FOUND)
 417
 418 option (LUGARU_FORCE_INTERNAL_GLU "Force internal libGLU, even if there's a system version" False)
 419 if (LUGARU_FORCE_INTERNAL_GLU)
 420         set(OPENGL_GLU_FOUND False)
 421 endif (LUGARU_FORCE_INTERNAL_GLU)
 422
 423 if (NOT OPENGL_GLU_FOUND)
 424     message(STATUS "Using internal copy of libGLU")
 425     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} GLU")
 426     set(GLUDIR "${DEPDIR}/GLU")
 427     set(GLU_INCLUDE_DIR "${GLUDIR}")
 428     set(GLU_LIBRARY "")
 429     set(LUGARU_SRCS
 430         ${LUGARU_SRCS}
 431         ${GLUDIR}/dict.c
 432         ${GLUDIR}/geom.c
 433         ${GLUDIR}/memalloc.c
 434         ${GLUDIR}/mesh.c
 435         ${GLUDIR}/mipmap.c
 436         ${GLUDIR}/normal.c
 437         ${GLUDIR}/priorityq.c
 438         ${GLUDIR}/render.c
 439         ${GLUDIR}/sweep.c
 440         ${GLUDIR}/tess.c
 441         ${GLUDIR}/tessmono.c
 442         ${GLUDIR}/util.c
 443     )
 444 endif (NOT OPENGL_GLU_FOUND)
 445
 446 option (LUGARU_FORCE_INTERNAL_VORBIS "Force internal Vorbis, even if there's a system version" False)
 447 if (NOT LUGARU_FORCE_INTERNAL_VORBIS)
 448     find_package(OggVorbis)
 449 else(NOT LUGARU_FORCE_INTERNAL_VORBIS)
 450         set(OGGVORBIS_FOUND False)
 451 endif (NOT LUGARU_FORCE_INTERNAL_VORBIS)
 452
 453 if (NOT OGGVORBIS_FOUND)
 454     message(STATUS "Using internal copy of Ogg Vorbis")
 455     set(LUGARU_MISSING_DEPS "${LUGARU_MISSING_DEPS} OggVorbis")
 456     set(OGGDIR "${DEPDIR}/libogg")
 457     set(OGG_INCLUDE_DIR "${OGGDIR}/include")
 458     set(OGG_LIBRARY "")
 459     set(VORBISDIR "${DEPDIR}/libvorbis")
 460     set(VORBISFILE_INCLUDE_DIR "${VORBISDIR}/include")
 461     set(VORBISFILE_LIBRARY "")
 462     set(LUGARU_SRCS
 463         ${LUGARU_SRCS}
 464         ${OGGDIR}/src/bitwise.c
 465         ${OGGDIR}/src/framing.c
 466         ${VORBISDIR}/lib/analysis.c
 467         ${VORBISDIR}/lib/bitrate.c
 468         ${VORBISDIR}/lib/block.c
 469         ${VORBISDIR}/lib/codebook.c
 470         ${VORBISDIR}/lib/envelope.c
 471         ${VORBISDIR}/lib/floor0.c
 472         ${VORBISDIR}/lib/floor1.c
 473         ${VORBISDIR}/lib/info.c
 474         ${VORBISDIR}/lib/lpc.c
 475         ${VORBISDIR}/lib/lsp.c
 476         ${VORBISDIR}/lib/mapping0.c
 477         ${VORBISDIR}/lib/mdct.c
 478         ${VORBISDIR}/lib/psy.c
 479         ${VORBISDIR}/lib/registry.c
 480         ${VORBISDIR}/lib/res0.c
 481         ${VORBISDIR}/lib/sharedbook.c
 482         ${VORBISDIR}/lib/smallft.c
 483         ${VORBISDIR}/lib/synthesis.c
 484         ${VORBISDIR}/lib/vorbisfile.c
 485         ${VORBISDIR}/lib/window.c
 486     )
 487 endif (NOT OGGVORBIS_FOUND)
 488
 489 include_directories(
 490     ${OPENAL_INCLUDE_DIR}
 491     ${JPEG_INCLUDE_DIR}
 492     ${PNG_INCLUDE_DIR}
 493     ${ZLIB_INCLUDE_DIR}
 494     ${OPENGL_INCLUDE_DIR}
 495     ${GLU_INCLUDE_DIR}
 496     ${SDL_INCLUDE_DIR}
 497     ${VORBISFILE_INCLUDE_DIR}
 498     ${OGG_INCLUDE_DIR}
 499     ${CMAKE_SOURCE_DIR}/Source
 500 )
 501
 502 set(LUGARU_LIBS ${OPENAL_LIBRARY} ${PNG_LIBRARY} ${JPEG_LIBRARY} ${ZLIB_LIBRARIES} ${SDL_LIBRARY} ${GLU_LIBRARY} ${OPENGL_LIBRARY} ${VORBISFILE_LIBRARY} ${OGG_LIBRARY} ${PLATFORM_LIBS})
 503
 504
 505 if(WIN32)
 506     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H} lugaru_resource.obj)
 507 else(WIN32)
 508     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H})
 509 endif(WIN32)
 510
 511 target_link_libraries(lugaru ${LUGARU_LIBS})
 512
 513 if(WIN32)
 514         add_definitions(-DUSE_OPENAL=1 -DUSE_SDL=1 -DBinIO_STDINT_HEADER=<stdint.h>)
 515 else(WIN32)
 516         add_definitions(-DPLATFORM_LINUX=1 -DPLATFORM_UNIX=1 -DUSE_OPENAL=1 -DUSE_SDL=1 -DBinIO_STDINT_HEADER=<stdint.h>)
 517 endif(WIN32)
 518
 519 # Install target
 520 if(APPLE)
 521         set(APPS_ROOT "${CMAKE_INSTALL_PREFIX}/Lugaru.app")
 522         set(APPS_BIN "${APPS_ROOT}/Contents/MacOS")
 523         set(APPS_DATA "${APPS_ROOT}/Contents/Resources")
 524 endif(APPLE)
 525
 526 if(WIN32)
 527         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru.exe DESTINATION ${CMAKE_INSTALL_PREFIX})
 528         if(MSVC80)
 529                 install(FILES ${SDLDIR}/lib/win32/msvc2005/SDL.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 530                 install(FILES ${OPENALDIR}/lib/win32/msvc2005/OpenAL32.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 531         endif(MSVC80)
 532         if(MSVC90)
 533                 install(FILES ${SDLDIR}/lib/win32/msvc2008/SDL.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 534                 install(FILES ${OPENALDIR}/lib/win32/msvc2008/OpenAL32.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 535         endif(MSVC90)
 536         if(MINGW)
 537                 install(FILES ${SDLDIR}/lib/win32/mingw/SDL.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 538                 install(FILES ${OPENALDIR}/lib/win32/mingw/OpenAL32.dll DESTINATION ${CMAKE_INSTALL_PREFIX})
 539         endif(MINGW)
 540 else(WIN32)
 541         if(APPLE)
 542                 set(CMAKE_INSTALL_PREFIX "${APPS_BIN}")
 543                 install(FILES ${SRCDIR}/mac-res/lugaru.icns DESTINATION ${APPS_DATA})
 544                 install(FILES ${SRCDIR}/mac-res/Info.plist DESTINATION ${APPS_ROOT}/Contents)
 545         endif(APPLE)
 546         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_PREFIX})
 547         if(APPLE AND LUGARU_HAS_INTERNAL_SDL)
 548                 install(FILES ${SDLDIR}/lib/macosx/libSDL-1.2.0.dylib DESTINATION ${CMAKE_INSTALL_PREFIX})
 549         endif(APPLE AND LUGARU_HAS_INTERNAL_SDL)
 550 endif(WIN32)
 551
 552 if(NOT APPLE)
 553 install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 554 endif(NOT APPLE)
 555
 556 if(APPLE)
 557 install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${APPS_ROOT})
 558 endif(APPLE)
 559
 560 if (LUGARU_MISSING_DEPS)
 561     message(STATUS "Using our copy of these libs: ${LUGARU_MISSING_DEPS}")
 562 endif (LUGARU_MISSING_DEPS)
 563