CMakeLists.txt

   1 project(lugaru)
   2
   3 cmake_minimum_required(VERSION 3.5)
   4 cmake_policy(SET CMP0004 OLD)
   5
   6 include(FindPkgConfig)
   7 include(GNUInstallDirs)
   8
   9 set(SRCDIR "${CMAKE_CURRENT_SOURCE_DIR}/Source")
  10
  11
  12 ### Helper
  13
  14 if(UNIX AND NOT APPLE)
  15     set(LINUX TRUE)
  16 endif()
  17
  18
  19 ### CMake config
  20
  21 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O0 --std=c++11")
  22 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Wall -Wno-parentheses -pedantic -g -pg --std=c++11")
  23 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Wall -Wno-parentheses -O2 -std=c++11")
  24
  25 if(APPLE)
  26     set(CMAKE_OSX_ARCHITECTURES "x86_64" CACHE STRING "Build architectures for OSX")
  27     set(CMAKE_OSX_DEPLOYMENT_TARGET "10.10" CACHE STRING
  28         "Minimum OS X version to target for deployment (at runtime); newer APIs weak linked. Set to empty string for default value")
  29     set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.10.sdk" CACHE PATH
  30         "The product will be built against the headers and libraries located inside the indicated SDK.")
  31 endif(APPLE)
  32
  33 if(LINUX)
  34     option(SYSTEM_INSTALL "Enable system-wide installation, with hardcoded data directory defined with CMAKE_INSTALL_DATADIR" OFF)
  35 endif(LINUX)
  36
  37 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  38
  39
  40 ### Sources
  41
  42 set(LUGARU_SRCS
  43     ${SRCDIR}/main.cpp
  44     ${SRCDIR}/Frustum.cpp
  45     ${SRCDIR}/Account.cpp
  46     ${SRCDIR}/ConsoleCmds.cpp
  47     ${SRCDIR}/Dialog.cpp
  48     ${SRCDIR}/Game.cpp
  49     ${SRCDIR}/GameDraw.cpp
  50     ${SRCDIR}/GameInitDispose.cpp
  51     ${SRCDIR}/GameTick.cpp
  52     ${SRCDIR}/Globals.cpp
  53     ${SRCDIR}/Lights.cpp
  54     ${SRCDIR}/Menu.cpp
  55     ${SRCDIR}/Models.cpp
  56     ${SRCDIR}/Objects.cpp
  57     ${SRCDIR}/pack.c
  58     ${SRCDIR}/Person.cpp
  59     ${SRCDIR}/private.c
  60     ${SRCDIR}/Quaternions.cpp
  61     ${SRCDIR}/Skeleton.cpp
  62     ${SRCDIR}/Skybox.cpp
  63     ${SRCDIR}/Sprite.cpp
  64     ${SRCDIR}/Terrain.cpp
  65     ${SRCDIR}/Texture.cpp
  66     ${SRCDIR}/Text.cpp
  67     ${SRCDIR}/ImageIO.cpp
  68     ${SRCDIR}/unpack.c
  69     ${SRCDIR}/Weapons.cpp
  70     ${SRCDIR}/openal_wrapper.cpp
  71     ${SRCDIR}/Input.cpp
  72     ${SRCDIR}/Settings.cpp
  73     ${SRCDIR}/Stereo.cpp
  74     ${SRCDIR}/Animation.cpp
  75     ${SRCDIR}/Sounds.cpp
  76     ${SRCDIR}/Awards.cpp
  77     ${SRCDIR}/Utils/Folders.cpp
  78 )
  79
  80 set(LUGARU_H
  81     ${SRCDIR}/Frustum.h
  82     ${SRCDIR}/Account.h
  83     ${SRCDIR}/ConsoleCmds.h
  84     ${SRCDIR}/Dialog.h
  85     ${SRCDIR}/Game.h
  86     ${SRCDIR}/Lights.h
  87     ${SRCDIR}/Menu.h
  88     ${SRCDIR}/Models.h
  89     ${SRCDIR}/Objects.h
  90     ${SRCDIR}/Person.h
  91     ${SRCDIR}/PhysicsMath.h
  92     ${SRCDIR}/Quaternions.h
  93     ${SRCDIR}/Random.h
  94     ${SRCDIR}/Skeleton.h
  95     ${SRCDIR}/Skybox.h
  96     ${SRCDIR}/Sprite.h
  97     ${SRCDIR}/ImageIO.h
  98     ${SRCDIR}/Terrain.h
  99     ${SRCDIR}/Texture.h
 100     ${SRCDIR}/Text.h
 101     ${SRCDIR}/Weapons.h
 102     ${SRCDIR}/Input.h
 103     ${SRCDIR}/binio.h
 104     ${SRCDIR}/openal_wrapper.h
 105     ${SRCDIR}/optionparser.h
 106     ${SRCDIR}/gamegl.h
 107     ${SRCDIR}/private.h
 108     ${SRCDIR}/Settings.h
 109     ${SRCDIR}/Stereo.h
 110     ${SRCDIR}/Animation.h
 111     ${SRCDIR}/Sounds.h
 112     ${SRCDIR}/Utils/Folders.h
 113 )
 114
 115 if(UNIX)
 116     set(LUGARU_SRCS
 117         ${LUGARU_SRCS}
 118         ${SRCDIR}/MacCompatibility.cpp
 119     )
 120     set(LUGARU_H
 121         ${LUGARU_H}
 122         ${SRCDIR}/MacCompatibility.h
 123     )
 124 endif(UNIX)
 125
 126 if(WIN32)
 127     add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 128                        COMMAND ${CMAKE_RC_COMPILER}
 129                        -I${SRCDIR}/win-res
 130                        -o ${CMAKE_CURRENT_BINARY_DIR}/lugaru_resource.obj
 131                        -i${SRCDIR}/win-res/Lugaru.rc
 132                        DEPENDS ${SRCDIR}/win-res/Lugaru.rc
 133     )
 134
 135     # FIXME: get rid of this.
 136     set(LUGARU_SRCS
 137         ${LUGARU_SRCS}
 138         ${SRCDIR}/WinDefs.cpp)
 139
 140     set(LUGARU_H
 141         ${LUGARU_H}
 142         ${SRCDIR}/WinDefs.h
 143         ${SRCDIR}/win-res/resource.h)
 144 endif(WIN32)
 145
 146 if(APPLE)
 147     set(PLATFORM_LIBS "-framework Carbon -framework Cocoa -framework OpenGL -framework OpenAL")
 148 endif(APPLE)
 149
 150
 151 ### Dependencies
 152
 153 find_package(OpenGL REQUIRED)
 154
 155 # Windows is funky about OpenAL detection
 156 if(WIN32)
 157     pkg_check_modules(OPENAL openal REQUIRED)
 158     set(OPENAL_LIBRARY ${OPENAL_LIBRARIES})
 159 else(WIN32)
 160     find_package(OpenAL REQUIRED)
 161 endif(WIN32)
 162
 163 find_package(sdl2 REQUIRED)
 164 find_package(PNG REQUIRED)
 165 find_package(JPEG REQUIRED)
 166 find_package(ZLIB REQUIRED)
 167 find_package(OggVorbis REQUIRED)
 168
 169 include_directories(
 170     ${OPENAL_INCLUDE_DIR}
 171     ${JPEG_INCLUDE_DIR}
 172     ${PNG_INCLUDE_DIR}
 173     ${ZLIB_INCLUDE_DIR}
 174     ${OPENGL_INCLUDE_DIR}
 175     ${SDL2_INCLUDE_DIRS}
 176     ${VORBISFILE_INCLUDE_DIR}
 177     ${OGG_INCLUDE_DIR}
 178     ${CMAKE_SOURCE_DIR}/Source
 179 )
 180
 181 set(LUGARU_LIBS ${OPENAL_LIBRARY} ${PNG_LIBRARY} ${JPEG_LIBRARY} ${ZLIB_LIBRARIES} ${SDL2_LIBRARIES} ${OPENGL_LIBRARIES} ${VORBISFILE_LIBRARY} ${OGG_LIBRARY} ${PLATFORM_LIBS})
 182
 183
 184 ### Definitions
 185
 186 if(WIN32)
 187     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H} lugaru_resource.obj)
 188 else(WIN32)
 189     add_executable(lugaru ${LUGARU_SRCS} ${LUGARU_H})
 190 endif(WIN32)
 191
 192 target_link_libraries(lugaru ${LUGARU_LIBS})
 193
 194 if(WIN32)
 195     add_definitions(-DBinIO_STDINT_HEADER=<stdint.h>)
 196     if(MINGW)
 197         # An alternative would be to use _WIN32 consistently instead of WIN32
 198         add_definitions(-DWIN32)
 199     endif(MINGW)
 200 else(WIN32)
 201     add_definitions(-DPLATFORM_LINUX=1 -DPLATFORM_UNIX=1 -DBinIO_STDINT_HEADER=<stdint.h>)
 202 endif(WIN32)
 203
 204
 205 ### Installation
 206
 207 if(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 208     set(CMAKE_INSTALL_PREFIX "C:/Lugaru")
 209 endif(NOT CMAKE_INSTALL_PREFIX AND WIN32)
 210
 211 # OS-specific installation paths
 212
 213 set(LUGARU_DOCDIR ${CMAKE_INSTALL_PREFIX})
 214 if(LINUX)
 215 endif(LINUX)
 216
 217 if(APPLE)
 218     set(LUGARU_APP_ROOT ${CMAKE_INSTALL_PREFIX}/Lugaru.app)
 219     set(LUGARU_BINDIR ${LUGARU_APP_ROOT}/Contents/MacOS)
 220     set(LUGARU_RESDIR ${LUGARU_APP_ROOT}/Resources)
 221 endif(APPLE)
 222
 223 # Actual installation instructions
 224
 225 if(WIN32)
 226     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru.exe DESTINATION ${CMAKE_INSTALL_PREFIX})
 227     if(MINGW)
 228         # Based off Mageia/Fedora MinGW toolchain, might not work on other distros or Windows
 229         set(LIBGCC_S libgcc_s_sjlj-1.dll)
 230         if(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64") # MinGW64
 231             set(LIBGCC_S libgcc_s_seh-1.dll)
 232         endif(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")
 233         # FIXME: Filter out unneeded DLLs when building against some internal deps
 234         set(DLL_ROOT ${CMAKE_FIND_ROOT_PATH}/bin)
 235         install(FILES ${DLL_ROOT}/${LIBGCC_S}
 236                       ${DLL_ROOT}/libjpeg-62.dll
 237                       ${DLL_ROOT}/libogg-0.dll
 238                       ${DLL_ROOT}/libpng16-16.dll
 239                       ${DLL_ROOT}/libstdc++-6.dll
 240                       ${DLL_ROOT}/libvorbis-0.dll
 241                       ${DLL_ROOT}/libvorbisfile-3.dll
 242                       ${DLL_ROOT}/libwinpthread-1.dll
 243                       ${DLL_ROOT}/OpenAL32.dll
 244                       ${DLL_ROOT}/SDL2.dll
 245                       ${DLL_ROOT}/zlib1.dll
 246                 DESTINATION ${CMAKE_INSTALL_PREFIX})
 247     endif(MINGW)
 248 endif(WIN32)
 249
 250 if(LINUX)
 251     if(SYSTEM_INSTALL)
 252         add_definitions(-DDATA_DIR="${CMAKE_INSTALL_FULL_DATADIR}/${PROJECT_NAME}")
 253         set(LUGARU_DOCDIR ${CMAKE_INSTALL_DOCDIR})
 254         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_BINDIR})
 255         # Trailing '/' is significant, it installs and _renames_ Data/ as the destination folder
 256         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data/ DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
 257         #install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/appdata)
 258         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 259         install(FILES ${CMAKE_SOURCE_DIR}/Dist/lugaru.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/128x128/apps)
 260     else(SYSTEM_INSTALL)
 261         message(WARNING "You are installing Lugaru without having enabled the SYSTEM_INSTALL option. It will default to looking for the data in the 'Data' directory next to the binary.")
 262         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${CMAKE_INSTALL_PREFIX})
 263         install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${CMAKE_INSTALL_PREFIX})
 264     endif(SYSTEM_INSTALL)
 265 endif(LINUX)
 266
 267 if(APPLE)
 268     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/lugaru DESTINATION ${LUGARU_BINDIR})
 269     install(DIRECTORY ${CMAKE_SOURCE_DIR}/Data DESTINATION ${LUGARU_APP_ROOT})
 270     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/lugaru.icns DESTINATION ${LUGARU_RESDIR})
 271     install(FILES ${CMAKE_SOURCE_DIR}/Dist/OSX/Info.plist DESTINATION ${LUGARU_APP_ROOT}/Contents)
 272 endif(APPLE)
 273
 274 # Documentation
 275
 276 install(FILES ${CMAKE_SOURCE_DIR}/README.md
 277               ${CMAKE_SOURCE_DIR}/COPYING.txt
 278               ${CMAKE_SOURCE_DIR}/CONTENT-LICENSE.txt
 279         DESTINATION ${LUGARU_DOCDIR})